您好，登录后才能下订单哦！
密码登录
登录注册
点击 登录注册 即表示同意《亿速云用户服务条款》
这篇文章主要介绍了如何使用XSL和ASP在线编辑XML文档，具有一定借鉴价值，感兴趣的朋友可以参考下，希望大家阅读完这篇文章之后大有收获，下面让小编带着大家一起了解一下。
本文通过一个详细的例子，来阐述了在线编辑XML文档数据的方法。由于Netscape对XML的支持比较弱，因此，要实现跨平台的数据交换，数据的处理必须在服务器端进行。要编辑XML文档，首先要做的事情就是怎样把这些数据提取并显示给访问者，XSL为我们显示XML文件提供了一个很好的解决方案。下面的例子就是利用XSL样式单把XML文档显示出来，供用户进行编辑，然后再把编辑后的数据提交到服务器，在服务器端进行数据的http://www.php.cn/php/php-tp-renewal.html" target="_blank">更新。这里采用ASP（Active Server Pages）来完成我们的任务。
首先，载入我们要进行编辑的XML文档，利用微软的文档对象模型（Microsoft XMLDOM Object）和XSL，XML文档就可以在服务器端转换成可以在客户端显示的HTML文件内容。下面先看看我们使用的XML和XSL文件是什么样子的。
XML文件：userdata.xml
<?xml version="1.0" encoding="gb2312"?> <用户资料> <field id="姓名" taborder="1"> <field_value>孟子</field_value> </field> <field id="性别" taborder="2"> <field_value>男</field_value> </field> <field id="单位名称" taborder="3"> <field_value>中国网络技术发展公司北京分公司</field_value> </field> <field id="详细地址" taborder="4"> <field_value>北京市嘉里中心102层</field_value> </field> <field id="电话" taborder="5"> <field_value>1391139136*</field_value> </field> <field id="电子邮件" taborder="6"> <field_value>amxh@21cn.com</field_value> </field> </用户资料> XSL文件：userdata.xsl <?xml version="1.0" encoding="gb2312" ?> <xsl:stylesheet xmlns:xsl="http://www.w3.org/TR/WD-xsl"> <xsl:template match="/"> <html> <meta http-equiv="Content-Type" content="text/html; charset=gb2312" /> <body> <form method="post" action="Edituserdata.asp"> <h2>用户资料编辑：</h2> <table border="1" cellpadding="2"> <xsl:for-each select="用户资料/field"> <tr> <td> <xsl:value-of select="@id"/> </td> <td> <input type="text"> <xsl:attribute name="id"> <xsl:value-of select="@id" /> </xsl:attribute> <xsl:attribute name="name"><xsl:value-of select="@id" /> </xsl:attribute> <xsl:attribute name="value"> <xsl:value-of select="field_value" /> </xsl:attribute></input> </td> </tr> </xsl:for-each> </table> <br /> <input type="submit" id="btnSubmit" name="btnSubmit" value="完成编辑" /> </form> </body> </html> </xsl:template> </xsl:stylesheet>
XSL文件使用了XSL：for-each元素的来遍历整个XML文件，XML文件里每个“field”元素的“id”属性和HTML表单的文本输入框的“id”和“name”想对应。这样，HTML表单的文本输入框就显示出了XML文件的元素值。此文件负责XML文档在服务器端的转换，以便能在各种浏览器上显示。
下面是关键的程序，它实现打开和更新XML文档的功能，并根据表单的提交与否，来决定是否进行更新。它包含了两个函数，loadXMLFile负责载入和转换要显示的XML文件；updateXML函数负责更新XML文件。
Edituserdata.asp程序如下：
<%
'-----------------------------------------------------------
'定义函数 loadXMLFile(),接收二个参数：
'strXMLFile - XML 文件的路径和文件名字
'strXSLFilee - XSL 文件的路径和文件名字
'-----------------------------------------------------------
Function loadXMLFile(strXMLFile, strXSLFile)
'Declare local variables
Dim objXML
Dim objXSL
'实例化 XMLDOM 对象，以便载入 XML 文件。
set objXML = Server.CreateObject("Microsoft.XMLDOM")
'关掉文件异步载入模式。
objXML.async = false
'载入 XML 文件！
objXML.load(strXMLFile)
'实例化 XMLDOM 对象，以便载入 XSL 文件。
set objXSL = Server.CreateObject("Microsoft.XMLDOM")
'关掉文件异步载入模式。
objXSL.async = false
'载入 XSL 文件！
objXSL.load(strXSLFile)
'利用 XMLDOM 的 transformNode 方法，把 XSL 样式表应用到 XML 文档，然后输出到客户端。
Response.Write(objXML.transformNode(objXSL))
End Function
'------------------------------------------------------------------
'函数 updateXML() 接收一个参数：strXMLFile - XML 文件的路径和文件名。
'------------------------------------------------------------------
Function updateXML(strXMLFile)
'声明局部变量。
Dim objDom
Dim objRoot
Dim objField
Dim x
'实例化 XMLDOM 对象。
set objDOM = Server.CreateObject("Microsoft.XMLDOM")
'关掉文件异步载入模式。
objDOM.async = false
'载入 XML 文件。
objDOM.load strXMLFile
'设定根元素。
Set objRoot = objDom.documentElement
'遍历 FORM 集合，并把提交的数据写入 XML 文件。
For x = 1 to Request.Form.Count
'检查提交的数据是否包含按钮。如果是，忽略此数据。
If instr(1,Request.Form.Key(x),"btn") = 0 Then
'按照 XSL 查询模式，建立 objField 变量，把表单的元素对应到 XML 文档里的相应元素[field_value]。
Set objField = objRoot.selectSingleNode("field[@id='" & Request.Form.Key(x) & "']/field_value")
'把表单提交的数据和 XML 文档里的节点值对应起来。
objField.Text = Request.Form(x)
End If
Next
'保存编辑过的 XML 文件。
objDom.save strXMLFile
'释放所有对对象的引用。
Set objDom = Nothing
Set objRoot = Nothing
Set objField = Nothing
'调用 loadXMLFile 函数，把新编辑后的 XML 文件用 updateduserdata.xsl 样式单显示到客户端。
loadXMLFile strXMLFile,server.MapPath("updateduserdata.xsl")
End Function
'检查表单是否成功提交，如提交，更新 XML 文件；否则，转到编辑状态。
If Request.Form("btnSubmit") = "" Then
loadXMLFile server.MapPath("userdata.xml"),server.MapPath("userdata.xsl")
Else
updateXML server.MapPath("userdata.xml")
End If
%>当表单提交成功后，我们用updateduserdata.xsl来显示我们刚刚编辑的数据。
updateduserdata.xsl如下：
<?xml version="1.0" encoding="gb2312" ?> <xsl:stylesheet xmlns:xsl="http://www.w3.org/TR/WD-xsl"> <xsl:template match="/"> <html> <meta http-equiv="Content-Type" content="text/html; charset=gb2312" /> <body> <h2>更新后的用户资料如下：</h2> <table border="1" cellpadding="2"> <xsl:for-each select="用户资料/field"> <tr> <td> <xsl:value-of select="@id" /> </td> <td> <xsl:value-of select="field_value" /> </td> </tr> </xsl:for-each> </table> <form> <input type="button" value="返回" onclick="history.go(-1)" /> </form> </body> </html> </xsl:template> </xsl:stylesheet>
感谢你能够认真阅读完这篇文章，希望小编分享的“如何使用XSL和ASP在线编辑XML文档”这篇文章对大家有帮助，同时也希望大家多多支持亿速云，关注亿速云行业资讯频道，更多相关知识等着你来学习!
免责声明：本站发布的内容（图片、视频和文字）以原创、转载和分享为主，文章观点不代表本网站立场，如果涉及侵权请联系站长邮箱：is@yisu.com进行举报，并提供相关证据，一经查实，将立刻删除涉嫌侵权内容。